// Script "MM_selviews.txt"
// -> select views in MM03

// Example (MM03 1st screen):  
//  Pushbutton (toolbar) "MyViews" process="MM_selviews.txt"
//        using V1 = "Basic data 1"
//        using V2 = "Basic data 2"
//        using V3 = "Quality Management"
  

// View names to be selected
Parameter V1  "N"
Parameter V2  "N"
Parameter v3  "N"
Parameter V4  "N"
 

// Variables
Set V[Z_abs] 1   // Absolute row number


label new_screen

Screen SAPLMGMM.0070 

  GetTableAttribute T[Table] LastVisibleRow=LVisRow  LastRow=LastRow

  Set V[Z_rel] 1  // Relative row number


  label new_row
 
  // Check view name
  Set V[view] "&cell[Table,1,&V[Z_rel]]"

  if V[view=&U[V1]] or V[view=&U[V2]] or V[view=&U[V3]] or V[view=&U[V4]]
    Set cell[Table,0,&V[Z_rel]] "X" 
  endif 

  Set V[Z_abs] &V[Z_abs] + 1 
  Set V[Z_rel] &V[Z_rel] + 1 

  // all rows processed?
  if  V[Z_abs>&V[LastRow]] 
    goto selection_done
  endif

  // end of screen? then scroll 
  if V[Z_abs>&V[LVisRow]] 
    Enter /ScrollToLine="&V[Z_abs]"  Table="T[Table]" 
    goto new_screen
  endif
 
  goto new_row

label selection_done