Funktion Mit DropDownList können Sie die Eingabe in einem SAP Standardfeld oder für eine eigene Variable als Auswahlliste anbieten.
Beispiele

Weitere Beispiele 		DropDownList (10,1) "currencylist" refer="F[Währung]"  width=20

Es wird eine Auswahlliste mit Werten aus dem Langtext  "currencylist" angezeigt. Der aktuelle Wert wird dem Feld F[Währung] entnommen und bei Selektion eines neuen Wertes dort zurückgestellt.

DropDownList (4,1) "countrylist" refer="V[XD_country]"  width=24

Es wird eine Auswahlliste mit Werten aus dem Langtext  "countrylist" angezeigt. Der aktuelle Wert wird der Variablen V[XD_country] entnommen und bei Selektion eines neuen Wertes dort zurückgestellt.
Format 1 DropDownList (Zeile,Spalte) "longtext" refer="name"   

Die Auswahlliste wird wie folgt aus dem Langtext "longtext" aufgebaut:

  • Jede Textzeile bildet einen Wert der Auswahlliste
  • Optional können Sie auch mehrere Werte in einer Textzeile unterbringen; dann bitte jeweils durch ein Semikolon voneinander trennen
  • Es kann entweder nur der Wert abgelegt sein, z.B. ein Währungsschlüssel EUR, SFR, ... Oder Sie legen zusätzlich einen beschreibenden Text ab. Nur der Text ist dann in der Auswahlliste sichtbar, während der Wert als Inhalt des Feldes oder der Variable dient. Das Format ist: wert=text, z.B. "BV=Barverkauf".
  • Sie können auch für einen leeren Wert einen Text aufnehmen. Er wird angezeigt, wenn das Feld bzw. die Variable leer sind. Beispiel: "=--- Auswahl Auftragsart  ---"

Den Langtext können Sie im Script mit festen Werten füllen (siehe Beispiel 1), aus einer Datei einlesen, in der Sie die Werte separat pflegen, oder aus der SAP Datenbank lesen, z.B. als Werte einer SAP Suchhilfe (Beispiel 2).
Format 2 DropDownList (Zeile,Spalte) table="V[varname]"    refer="name"   

Die Auswahlliste wird  aus der GuiXT Tabellenvariablen V[varname] aufgebaut. Die erste Spalte ist der Schlüssel, die zweite der Text.
Die Schlüssel werden automatisch angezeigt, falls die SAP GUI Option auf "Anzeige Schlüsselwerte" steht oder eine der  Optionen -showKeysund  -hideKeysangegeben ist.
Optionen
process= Angabe eines InputScripts, das bei Änderung der Auswahl in der dropdown Liste aufgerufen wird.
width= Breite der Auswahlliste (Anzahl Spalten). Default ist 16.
textFont= Gewünschter Font. Default ist "Arial".
textHeight= Texthöhe in Pixel. Der Default ist abhängig von der eingestellten SAP GUI Fontgröße.
textWeight= Schriftdicke zwischen 1 (dünn) bis 9 (sehr dick). Default ist 5.
-readOnly Nur der aktuelle Eintrag wird angezeigt, keine Änderung möglich
-noSort Die Einträge der dropdownlist werden bei der Anzeige nicht sortiert
-showKeys Die Schlüsselwerte werden vor dem Text ebenfalls angezeigt (nur in Verbindung mit table=)
-hideKeys Die Schlüsselwerte werden nicht angezeigt (nur in Verbindung mit table=)
-hideText Der Text wird im Kopffeld der Dropdownliste nicht angezeigt (nur in Verbindung mit table=)
Beispiel 1 GuiXT 
// VA01 Auftragsart
del F[Auftragsart] -triple
Set text[o1] "=--- Auswahl Auftragsart ---;"
Set text[o2] "TA=Terminauftrag;"
Set text[o3] "BV=Barverkauf;"
Set text[o4] "RE=Retoure;"

Set text[ordertypes] "&text[o1]&text[o2]&text[o3]&text[o4]"

DropDownList (2,0) "ordertypes" refer="F[Auftragsart]" width=30
Beispiel 2 GuiXT 
// Auswahl Auftragsgund gemäss Tabelle TVAUT

// GuiXT Struktur und Tabellenvariable für Open Call interface
CreateStructure V[ui_ddltabline] key text
CreateTable V[ui_ddltab_va01_augru] key text
 
// Parameter setzen um Texttabelle zu lesen
Set V[ui_table] "TVAUT"
Set V[ui_condition] "SPRAS = '&V[_language]' "
Set V[ui_fields] "AUGRU,BEZEI"
 
// Tabelle über RFC lesen
Call /guixt/dbselect _
  export.table="ui_table" _
  export.condition="ui_condition" _
  export.fields="ui_fields" _
  import.values="ui_ddltab_va01_augru"
 
// plus einen leeren Eintrag (wird automatisch nach oben sortiert
Clear V[ui_ddltabline]
AppendRow V[ui_ddltabline] table=V[ui_ddltab_va01_augru]

// dropdown-Liste anzeigen
Text (19,2) "Auftragsgrund" size=28 -label
DropDownList (19,30) table=V[ui_ddltab_va01_augru] _ 
	width="50" refer="V[ui_va01.augru]"
Tips & Tricks
Komponente GuiXT + InputAssistant