﻿
//-------------------------------- 
// CIS Migration ERP -> S/4HANA
//-------------------------------- 

// disableprocessing  step limit
ProcessingOption  maxstepcount=0 

// display status message
StatusMessage title="CIS visit export" addstring="Export starts"
StatusMessage  addstring=""


// set file names
Set V[FILE_VBKA]    "&V[exportfolder]\vbka.txt"

// we will need a TAB character later on
Set text[TAB] "x"
ReplaceText "TAB" from="x" toHexCode="09"
Set V[TAB] "&text[TAB]"


// Date formats yyyymmdd
// use date calculations to force a specific date format
Set V[diff] "&V[date1]" - "01.01.1900"
Set V[d] "01.01.1900" + "&V[diff]"
Set V[d1] "&V[d](7-10)&V[d](4-5)&V[d](1-2)"

Set V[diff] "&V[date2]" - "01.01.1900"
Set V[d] "01.01.1900" + "&V[diff]"
Set V[d2] "&V[d](7-10)&V[d](4-5)&V[d](1-2)"


// Initialize CIS interface
Set text[reqp] "ZM"
Clear text[resp]

Call "/GUIXT/CIS_INTERFACE"  _
in.REQUESTNAME="USER_SETTINGS" _
table.reqparm="reqp"


// --------------------
// General visit info
// --------------------
StatusMessage  addstring="Step 1 of 3: General visit info"



// all document numbers
Clear text[vbeln]

// Field list
Set text[fields] "VBELN,KUNNR,VKORG,VTWEG,SPART,KTAAR,KTABG,KTABT,KTAEN,KTAET,KTAGR,KTAST,KTAER,KTAEB,KTA01,KTA02,KTA03,KTA04,KTA05,KTA06,KTA07,KTA08,KTA09,KTA10,KTEXT,KALE,ERNAM,ERDAT,AENAM,AEDAT"

// one field name in each line 
ReplaceText "fields" from="," toHexcode="0d0a"

// condition
Set text[options] "KTABG BETWEEN '&V[d1]' AND '&V[d2]' "

// Read VBKA
Clear text[data]
call "RFC_READ_TABLE" _ 
	in.QUERY_TABLE="VBKA" _
	in.DELIMITER="&V[TAB]" _ 
	table.OPTIONS="options" _
	table.FIELDS="fields" _
	table.DATA="data"


Set V[k] 1
OpenFile "&V[FILE_VBKA]" -output
label visit_1
CopyText fromText="data" toString="wa" line=&V[k]
if Q[ok]
  AppendFile "&V[FILE_VBKA]"  wa
  
  // collect document numbers
  CopyText fromString="wa" toText="info"
  CopyText fromText="info" toString="VBELN" line=1 delimiter="&V[TAB]" 
  CopyText toText="vbeln" fromString="VBELN" -appendline
  
  Set V[k] &V[k] + 1 
  goto visit_1 
endif

CloseFile "&V[FILE_VBKA]"  


Set V[rcount1] &V[k] - 1
StatusMessage  addstring="  &V[rcount1] visits selected"
StatusMessage  addstring="  File &V[FILE_VBKA] generated"
StatusMessage  addstring="  Step 1 done"
StatusMessage  addstring=""


// ----------
// Partner, Texts
// ----------
StatusMessage  addstring="Step 2 of 3: Visit details (partners, texts)"

Set V[k] 1
Set V[n] 1
label detail_1
CopyText fromText="vbeln" toString="VBELN" line=&V[k]

if Q[ok]
  Set text[reqp] "&V[VBELN]"
  Clear text[resp]
  
  Call "/GUIXT/CIS_INTERFACE"  _
  in.REQUESTNAME="CUSTOMER_VISIT_DETAIL" _
  table.reqparm="reqp"  _
  table.resparm(width:400)="resp"
  
  Set V[FILE_VISIT_DETAIL]    "&V[exportfolder]\visit.&V[VBELN].txt"
  
  CopyText fromText="resp" toFile="&V[FILE_VISIT_DETAIL]" 
  
  // statusmessage for every 1000 files
  if V[n=1000]
    StatusMessage  addstring="  Please wait... &V[k] of &V[rcount1] files generated"
    Set V[n] 0
  endif
  
  
  Set V[k] &V[k] + 1 
  Set V[n] &V[n] + 1 
  
  goto detail_1
endif

Set V[k] &V[k] - 1
StatusMessage  addstring="  &V[k] visit files generated"
StatusMessage  addstring="  Step 2 done"
StatusMessage  addstring=""


// ------------
// Attachments
// ------------
StatusMessage  addstring="Step 3 of 3: Attachments"


Set V[k] 1
Set V[attachment_count] 0
label attachment_1
CopyText fromText="vbeln" toString="VBELN" line=&V[k]

if Q[ok]
  Set text[reqp] "&V[VBELN]"
  Clear text[resp]
  
  Call "/GUIXT/CIS_INTERFACE"  _
  in.REQUESTNAME="VISIT_ATTACHMENTS" _
  table.reqparm="reqp"  _
  table.resparm(width:200)="resp"
  
  if text[resp]
    Set V[FILE_VISIT_ATTACHMENTS]    "&V[exportfolder]\attachments.&V[VBELN].txt"
    CopyText fromText="resp" toFile="&V[FILE_VISIT_ATTACHMENTS]" 
    
    Set V[m] 1
    label attachment_2
    CopyText fromText="resp" toString="attinfo" line=&V[m]
    
    if Q[ok]
      Set V[attachment_count] &V[attachment_count] + 1
      
      // parse attachment info
      Set text[attinfo] "&V[attinfo]"
      CopyText fromText="attinfo" toString="id" line=1 delimiter="&V[TAB]"
      
      // read attachment
      Set text[attreqp] "&V[id]"
      Clear text[attresp]
      
      Call "/GUIXT/CIS_INTERFACE"  _
      in.REQUESTNAME="READ_ATTACHMENT" _
      table.reqparm="attreqp"  _
      table.resparm(width:4000)="attresp"  
      
      // generate attachment file
      Set V[FILE_VISIT_ATTACHMENT]    "&V[exportfolder]\attachment-&V[id].txt"
      CopyText fromText="attresp" toFile="&V[FILE_VISIT_ATTACHMENT]"  
      
      Set V[m] &V[m] + 1
      goto attachment_2
    endif
    
  endif
  
  Set V[k] &V[k] + 1 
  goto attachment_1
endif

StatusMessage  addstring="  &V[attachment_count] attachment files generated"
StatusMessage  addstring="  Step 3 done"
StatusMessage  addstring=""
StatusMessage  addstring="Export done"
