﻿// disableprocessing  step limit
ProcessingOption  maxstepcount=0 

// display status message
StatusMessage title="Import" addstring="Import attachments"
StatusMessage  addstring=""

// set import directory
Set V[EXPORT_DIRECTORY]        "&V[exportfolder]"

// we will need a TAB character later on
Set text[TAB] "x"
ReplaceText "TAB" from="x" toHexCode="09"
Set V[TAB] "&text[TAB]"



// -----------------------
// import attachments
// -----------------------
CopyText toText="attachments" fromDirectory="&V[EXPORT_DIRECTORY]\attachments.*"


Set V[k] 1
Set V[n] 1
label import_attachment
CopyText fromText="attachments" toString="filename" line="&V[k]"
if Q[ok]

  // get document number from filename
  Set text[temp] "&V[filename]"  // e.g. "attachments.0100001432.txs"
  CopyText fromText="temp" toString="VBELN" line=2 delimiter="."
//-------------------------------- 
// CIS Migration ERP -> S/4HANA
//-------------------------------- 
  
  Set V[filepath] "&V[EXPORT_DIRECTORY]\&V[filename]"

  CopyText toText="attinfo" fromFile="&V[filepath]"

  // attachment info
  CopyText fromText="attinfo" toString="extid" line=1 delimiter="&V[TAB]"
  CopyText fromText="attinfo" toString="dtype" line=2 delimiter="&V[TAB]"
  CopyText fromText="attinfo" toString="title" line=4 delimiter="&V[TAB]"
  CopyText fromText="attinfo" toString="bleng" line=5 delimiter="&V[TAB]"
  CopyText fromText="attinfo" toString="busxx" line=9 delimiter="&V[TAB]"

  // file name for content
  Set V[contentfilename] "&V[EXPORT_DIRECTORY]\attachment-&V[extid].txt"
  CopyText toText="content" fromFile="&V[contentfilename]"
 

  // build parameters

  // ERP document number
  Set text[reqp] "ERP:&V[VBELN]"

  // document title
  CopyText toText="reqp" fromString="title" -appendline

  CopyText fromText="content" toText="reqp" -appendline

  Clear text[resp]

 
 //CopyText fromText="reqp" toFile="C:\temp\reqp.txt"
 //return

  Call "/GUIXT/CIS_INTERFACE"  _
  in.REQUESTNAME="CREATE_VISIT_ATTACHMENT" _
  table.reqparm(width:4000)="reqp"  _
  table.resparm(width:100)="resp"



  
  // no commit work necessary, included in create_visit_attachment

  // statusmessage for every 10 files
  if V[n=10]
    StatusMessage  addstring="  Please wait... &V[k] visit attachments imported"
    Set V[n] 0
  endif
  
  Set V[k] &V[k] + 1
  Set V[n] &V[n] + 1

  goto import_attachment
endif

Set V[k] &V[k] - 1

StatusMessage  addstring=""
StatusMessage  addstring="&V[k] visit attachments imported"

StatusMessage  addstring=""
StatusMessage  addstring="Import done"
