﻿//-------------------------------- 
// CIS Migration ERP -> S/4HANA
//-------------------------------- 

// disableprocessing  step limit
ProcessingOption  maxstepcount=0 

// display status message
StatusMessage title="Import" addstring="Import starts"
StatusMessage  addstring=""

// set import directory
Set V[IMPORT_DIRECTORY]        "&V[importfolder]"

// --------------------
// import visits
// --------------------
CopyText toText="visitfiles" fromDirectory="&V[IMPORT_DIRECTORY]\visit.*"


Set V[k] 1
Set V[n] 1
label import_visit
CopyText fromText="visitfiles" toString="filename" line="&V[k]"
if Q[ok]
  Set V[filepath] "&V[IMPORT_DIRECTORY]\&V[filename]"
  CopyText toText="reqp" fromFile="&V[filepath]"
  Clear text[resp]
  
  Call "/GUIXT/CIS_INTERFACE"  _
  in.REQUESTNAME="CUSTOMER_VISIT_CHANGE" _
  table.reqparm="reqp"  _
  table.resparm(width:400)="resp"

 // statusmessage for every 1000 files
  if V[n=1000]
    StatusMessage  addstring="  Please wait... &V[k] visits imported"
    Set V[n] 0
  endif

  
  Set V[k] &V[k] + 1
  Set V[n] &V[n] + 1
  goto import_visit
endif

Set V[k] &V[k] - 1

StatusMessage  addstring=""
StatusMessage  addstring="&V[k] visits imported"





// --------------------
// import text files
// --------------------
CopyText toText="textfiles" fromDirectory="&V[IMPORT_DIRECTORY]\visittext.*"


Set V[k] 1
Set V[n] 1
label import_textfile
CopyText fromText="textfiles" toString="filename" line="&V[k]"
if Q[ok]
  Set V[filepath] "&V[IMPORT_DIRECTORY]\&V[filename]"
  CopyText toText="reqp" fromFile="&V[filepath]"

 
  Clear text[resp]
  
  Call "/GUIXT/CIS_INTERFACE"  _
  in.REQUESTNAME="VISIT_UPDATE_TEXT" _
  table.reqparm="reqp"  _
  table.resparm(width:100)="resp"
  
  // commit work
  Call "/GUIXT/CIS_INTERFACE"  _
  in.REQUESTNAME="COMMIT" 

// statusmessage for every 1000 files
  if V[n=1000]
    StatusMessage  addstring="  Please wait... &V[k] visit texts imported"
    Set V[n] 0
  endif
  
  Set V[k] &V[k] + 1
  Set V[n] &V[n] + 1

  goto import_textfile
endif

Set V[k] &V[k] - 1

StatusMessage  addstring=""
StatusMessage  addstring="&V[k] visit text files imported"

StatusMessage  addstring=""
StatusMessage  addstring="Import done"
