﻿//-------------------------------- 
// CIS Migration ERP -> S/4HANA
//-------------------------------- 

// disableprocessing  step limit
ProcessingOption  maxstepcount=0 

// display status message
StatusMessage title="Preparation of characteristics files" addstring="Preparation starts"
StatusMessage  addstring=""


// set file names
Set V[FILE_VBKA]        "&V[exportfolder]\vbka.txt"

// counter for status message
Set V[k] 1
Set V[n] 1


OpenFile "&V[FILE_VBKA]"

label import_1
ReadFile "&V[FILE_VBKA]"  _
VBELN KUNNR VKORG VTWEG SPART KTAAR KTABG KTABT KTAEN KTAET KTAGR KTAST KTAER KTAEB KTA01 KTA02 KTA03 KTA04 KTA05 KTA06 KTA07 KTA08 KTA09 KTA10 KTEXT KALE

if Q[ok]

  // read new document number
  // Field list
   Set text[fields] "OBJECT_ID"

// condition
Set text[options] "OBJTYPE_H = 'BUS2000126' and  EXTERN_ACT_ID = '&V[VBELN]' "

// Read VBKA
Clear text[data]
call "RFC_READ_TABLE" _ 
	in.QUERY_TABLE="CRMS4D_ACTV_H" _
	table.OPTIONS="options" _
	table.FIELDS="fields" _
	table.DATA="data"

  Set V[OBJECT_ID] "&text[data]"

  // build parameter file for characteristics update
  Clear text[resp]
   
  // 1  CLASS 
  Set V[par] "CIS_THEMEN"
  CopyText fromString="par" toText="resp" -appendline
   
  // 2 KLART
  Set V[par] "Z99"
  CopyText fromString="par" toText="resp" -appendline

  // 3 language
  Set V[par] "&V[_language]"
  CopyText fromString="par" toText="resp" -appendline
  
  // 4 key
  Set V[par] "BUS2000126&V[OBJECT_ID]"
  CopyText fromString="par" toText="resp" -appendline
  
  // 5 not used
  Set V[par] ""
  CopyText fromString="par" toText="resp" -appendline
  
  
  // 6 and following: characteristics

  // 1 CIS_THEMA_REIFEN
  Set V[merkmal] "CIS_THEMA_REIFEN"
  Set V[value]   "&V[KTA01]"
  goto generate_merkmal
  label CIS_THEMA_REIFEN

  // 2 CIS_THEMA_SCHMIERMITTEL
  Set V[merkmal] "CIS_THEMA_SCHMIERMITTEL"
  Set V[value]   "&V[KTA02]"
  goto generate_merkmal
  label CIS_THEMA_SCHMIERMITTEL

  // 3 CIS_THEMA_S_UND_V
  Set V[merkmal] "CIS_THEMA_S_UND_V"
  Set V[value]   "&V[KTA03]"
  goto generate_merkmal
  label CIS_THEMA_S_UND_V

  //  4 CIS_THEMA_ZUBEHOER
  Set V[merkmal] "CIS_THEMA_ZUBEHOER"
  Set V[value]   "&V[KTA04]"
  goto generate_merkmal
  label CIS_THEMA_ZUBEHOER

  // 5 CIS_THEMA_GAE
  Set V[merkmal] "CIS_THEMA_GAE"
  Set V[value]   "&V[KTA05]"
  goto generate_merkmal
  label CIS_THEMA_GAE

  // 6 CIS_THEMA_AWT_CEN
  Set V[merkmal] "CIS_THEMA_AWT_CEN"
  Set V[value]   "&V[KTA06]"
  goto generate_merkmal
  label CIS_THEMA_AWT_CEN

  // 7 CIS_THEMA_DEALS
  Set V[merkmal] "CIS_THEMA_DEALS"
  Set V[value]   "&V[KTA07]"
  goto generate_merkmal
  label CIS_THEMA_DEALS

  // 8 CIS_THEMA_KONZEPTE
  Set V[merkmal] "CIS_THEMA_KONZEPTE"
  Set V[value]   "&V[KTA08]"
  goto generate_merkmal
  label CIS_THEMA_KONZEPTE

  // 9 CIS_THEMA_SONSTIGES
  Set V[merkmal] "CIS_THEMA_SONSTIGES"
  Set V[value]   "&V[KTA09]"
  goto generate_merkmal
  label CIS_THEMA_SONSTIGES



  // generate file
  Set V[FILE_CHAR_IMPORT]    "&V[importfolder]\char.&V[VBELN].&V[OBJECT_ID].txt"
  CopyText fromText="resp" toFile="&V[FILE_CHAR_IMPORT]" 
  
  
  // statusmessage for every 1000 files
  if V[n=1000]
    StatusMessage  addstring="  Please wait... &V[k] files generated"
    Set V[n] 0
  endif
  
  
  Set V[k] &V[k] + 1 
  Set V[n] &V[n] + 1 
  
  
  goto import_1
endif
CloseFile "&V[FILE_VBKA]"  

Set V[k] &V[k] - 1
StatusMessage  addstring=""
StatusMessage  addstring="&V[k] characteristics files prepared for import"

StatusMessage  addstring=""
StatusMessage  addstring="Preparation done"

Return

// ---------------------------------------------
// pseudo-subroutine for parameter generation
// ---------------------------------------------
label generate_merkmal

  CopyText fromString="merkmal" toText="resp" -appendline
  Set V[par] "1"
  CopyText fromString="par" toText="resp" -appendline
  if V[value=10]
     Set V[par] ""
  else
     Set V[par] "X"  
  endif
  CopyText fromString="par" toText="resp" -appendline 
  
  CopyText fromString="merkmal" toText="resp" -appendline
  Set V[par] "2"
  CopyText fromString="par" toText="resp" -appendline
  if V[value=20]
     Set V[par] ""
  else
     Set V[par] "X"
  endif
  CopyText fromString="par" toText="resp" -appendline 

  CopyText fromString="merkmal" toText="resp" -appendline
  Set V[par] "3"
  CopyText fromString="par" toText="resp" -appendline
  if V[value=30]
     Set V[par] ""
  else
     Set V[par] "X"
  endif
  CopyText fromString="par" toText="resp" -appendline 

  // return
  goto &V[merkmal]
