﻿
//-------------------------------- 
// CIS Migration ERP -> S/4HANA
//-------------------------------- 


// disableprocessing  step limit
ProcessingOption  maxstepcount=0 

// display status message
StatusMessage title="Preparation of import files" addstring="Preparation starts"
StatusMessage  addstring=""


// set file names
Set V[FILE_VBKA]        "&V[exportfolder]\vbka.txt"


// counter for status message
Set V[k] 1
Set V[n] 1


OpenFile "&V[FILE_VBKA]"

label import_1
ReadFile "&V[FILE_VBKA]"  _
VBELN KUNNR VKORG VTWEG SPART KTAAR KTABG KTABT KTAEN KTAET KTAGR KTAST KTAER KTAEB _
KTA01 KTA02 KTA03 KTA04 KTA05 KTA06 KTA07 KTA08 KTA09 KTA10 KTEXT KALE ERNAM ERDAT AENAM AEDAT

if Q[ok]
  // build parameter file for visit creation 
   
  // 1  VBELN 
  Set  text[resp] "ERP:&V[VBELN]"
   
  // 2 VKORG
  Set V[par] "1000"
  CopyText fromString="par" toText="resp" -appendline
  
  // 3 VTWEG
  CopyText fromString="VTWEG" toText="resp" -appendline
  
  // 4 SPART
  CopyText fromString="VTWEG" toText="resp" -appendline
  
  // 5 partner_fct_ag
  Set V[par] "00000001"
  CopyText fromString="par" toText="resp" -appendline
  
  // 6 partner_fct_ap
  Set V[par] "00000015"
  CopyText fromString="par" toText="resp" -appendline
  
  // 7 partner_fct_zm
  Set V[par] "00000009"
  CopyText fromString="par" toText="resp" -appendline
  
  // 8 processtype
  CopyText fromString="KTAAR" toText="resp" -appendline
  
  // 9 description
  CopyText fromString="KTEXT" toText="resp" -appendline
  
  // 10 status
  if V[KTAST=0]
    Set V[par] "E0001"
  else
    Set V[par] "E0002"
  endif
  CopyText fromString="par" toText="resp" -appendline
  
  // 11 reason
  if V[KTAGR]
    Set V[par] "Z0000001.&V[KTAGR]"
  else
    Set V[par] ""
  endif
  CopyText fromString="par" toText="resp" -appendline
  
  // 12 result
  if V[KTAER]
    Set V[par] "Z0000001.&V[KTAER]"
  else
    Set V[par] ""
  endif
  CopyText fromString="par" toText="resp" -appendline
  
  // 13 KTABG
  CopyText fromString="KTABG" toText="resp" -appendline
  
  // 14 KTABT
  CopyText fromString="KTABT" toText="resp" -appendline
  
  // 15 KTAEN
  CopyText fromString="KTAEN" toText="resp" -appendline
  
  // 16 KTAET
  CopyText fromString="KTAET" toText="resp" -appendline
  
  // 17 CRM_SUBJECT_GR
  Set V[par] "Z00000001"
  CopyText fromString="par" toText="resp" -appendline
  
  // 18 CRM_SUBJECT_ER
  Set V[par] "Z00000002"
  CopyText fromString="par" toText="resp" -appendline
  
  // 19 etc. variable info
    
  // customer number
  Set V[par] "PAR:00000001.&V[KUNNR]"   
  CopyText fromString="par" toText="resp" -appendline  

  // ernam
  Set V[par] "ERN:&V[ERNAM]"   
  CopyText fromString="par" toText="resp" -appendline

  // erdat
  Set V[par] "ERD:&V[ERDAT]"   
  CopyText fromString="par" toText="resp" -appendline    


  if V[AENAM] 
    // aenam
    Set V[par] "AEN:&V[AENAM]"   
    CopyText fromString="par" toText="resp" -appendline    

    // aedat
    Set V[par] "AED:&V[AEDAT]"   
    CopyText fromString="par" toText="resp" -appendline 
  else
     // ernam
    Set V[par] "AEN:&V[ERNAM]"   
    CopyText fromString="par" toText="resp" -appendline    

    // erdat
    Set V[par] "AED:&V[ERDAT]"   
    CopyText fromString="par" toText="resp" -appendline 
  endif       
  
// read partners
  Set V[FILE_VISIT_DETAIL]    "&V[exportfolder]\visit.&V[VBELN].txt"
  OpenFile "&V[FILE_VISIT_DETAIL]"
  Clear V[parvw]
  label prepare_partners
  ReadFile "&V[FILE_VISIT_DETAIL]" parvw nrart function key fullname
  if Q[ok] and not V[parvw=TXT]    // read until start of texts
    if V[parvw=AP]
      Set V[par] "BPX:00000015.&V[key]"   
      CopyText fromString="par" toText="resp" -appendline
    endif
    if V[parvw=ZM]
      Set V[par] "PAR:00000009.EE&V[key]"   
      CopyText fromString="par" toText="resp" -appendline 
    endif
    goto prepare_partners
  endif 
  
  // generate file
  Set V[FILE_VISIT_IMPORT]    "&V[importfolder]\visit.&V[VBELN].txt"
  CopyText fromText="resp" toFile="&V[FILE_VISIT_IMPORT]" 
  
  Set V[textfileno] 0

  // generate text import file
  label prepare_next_text
  if V[parvw=TXT]
    Clear text[resp]
    Set V[textid] "&V[nrart]"
    Set V[linecount] "&V[key]" * 1
    Set V[title] "&V[function]"
    set V[titleleng] "&V[title]" -stringlength
    Set V[textlanguage] "&V[_language]"
    // determine language key
    Set V[x]  "&V[title]" search=" [DE]"
    if q[ok]
      Set V[textlanguage] "D"
      Set V[titleleng] &V[titleleng] - 5 
      Set V[title] "&V[title](1-&V[titleleng])" 
    endif
    Set V[x]  "&V[title]" search=" [FR]"
    if q[ok]
      Set V[textlanguage] "F"
      Set V[titleleng] &V[titleleng] - 5 
      Set V[title] "&V[title](1-&V[titleleng])" 
    endif
    Set V[x]  "&V[title]" search=" [IT]"
    if q[ok]
      Set V[textlanguage] "I"
      Set V[titleleng] &V[titleleng] - 5 
      Set V[title] "&V[title](1-&V[titleleng])" 
    endif

    // 1st parameter: document number 
    Set  V[par] "ERP:&V[VBELN]"
    CopyText fromString="par" toText="resp" 

    // 2nd parameter: language 
    CopyText fromString="textlanguage" toText="resp"  -appendline 

    // 3rd parameter: text id
    Set  V[par] "A004"
    CopyText fromString="par" toText="resp"  -appendline 

    // 4th and following: text lines. 
    // format:
    //   / new paragraph 
    //   = continuation line   

    // increase text file number
    Set V[textfileno] &V[textfileno] + 1

    Clear text[tlines]
    label prepare_text_lines
    if V[linecount>0]
        ReadFile "&V[FILE_VISIT_DETAIL]" wa 

        Set V[wastart] "&V[wa](1-3)"
        if V[wastart=<P>]
          Set V[wa] "/ &V[wa](4-200)"
        else 
          Set V[wa] "=  &V[wa]"
        endif  
 
        CopyText fromString="wa" toText="tlines" -appendline 

      Set V[linecount] &V[linecount] - 1
      goto prepare_text_lines
    endif

    // replace special HTML strings
    ReplaceText "tlines" from="&amp;" to="&" 
    ReplaceText "tlines" from="&lt;" to="<" 
    ReplaceText "tlines" from="&gt;" to=">" 

    // remove end of paragraph
    ReplaceText "tlines" from="</P>" to="" 

    CopyText fromText="tlines" toText="resp" -appendline


    // generate text import file
    Set V[FILE_VISITTEXT_IMPORT]    "&V[importfolder]\visittext.&V[VBELN].&V[textfileno].txt"
    CopyText fromText="resp" toFile="&V[FILE_VISITTEXT_IMPORT]"  

    Clear V[parvw]
    ReadFile "&V[FILE_VISIT_DETAIL]" parvw nrart function key fullname
    goto prepare_next_text
  endif 
  
  
  
  CloseFile "&V[FILE_VISIT_DETAIL]"
  
  // statusmessage for every 1000 files
  if V[n=1000]
    StatusMessage  addstring="  Please wait... &V[k] files generated"
    Set V[n] 0
  endif
  
  
  Set V[k] &V[k] + 1 
  Set V[n] &V[n] + 1 
  
  
  goto import_1
endif
CloseFile "&V[FILE_VBKA]"  

Set V[k] &V[k] - 1
StatusMessage  addstring=""
StatusMessage  addstring="&V[k] visit files prepared for import"

StatusMessage  addstring=""
StatusMessage  addstring="Preparation done"
