Purpose
Add a button in SAP GUI to launch a Fiori app directly.

SAP provides two main user interfaces: the classic SAP GUI and the Fiori apps. While Fiori emphasizes mobile accessibility and role-based design, most professional users still work on desktop PCs and prioritize speed, precision, and familiarity — making SAP GUI their preferred environment. When optimized with GuiXT, SAP GUI becomes even more powerful, offering streamlined workflows tailored to individual needs.

At the same time, Fiori apps — whether part of the SAP standard or developed in-house — can deliver valuable enhancements to traditional transactions.

With GuiXT, these apps can be integrated directly into the SAP GUI, allowing users to launch them with a single click from within their usual desktop interface.

Solution
Construct a URL using Fiori’s intent-based navigation, including key fields from the current SAP GUI transaction as parameters. Then use the Start command to launch the Fiori app directly.

Example
 In transaction IW38 (Maintenance Orders), we add a button that launches the 360° Customer View for the customer listed in the selected grid line. This allows users to access detailed customer insights directly from SAP GUI with a single click.

The following video illustrates the functionality and integration we're aiming for:

Video


Show video in full screen

GuiXT 
if Q[transaction=IW38]
  PushButton (toolbar) _
    "@R3\QShow Customer 360° View (Fiori)@Customer 360° View" _
       process="iw38_startfiori.txt"   
endif

 

GuiXT 
// InputScript iw38_startfiori.txt

// read customer number of selected row
CallVB guinet.gridcontrol.getselectedrows colids:="KUNUM"


// more than 1 line selected ?
CopyText fromText="_grid_selected_values" toString="customernumber" line=2
if V[customernumber]
  Return "E: Please select only one line" -statusline
endif

CopyText fromText="_grid_selected_values" toString="customernumber" line=1

// no grid line selected ?
if not V[customernumber]
  Return "E: Please select an order" -statusline
endif

// Build up Fiori URL
Set V[fiori_home] "https://synactivecloud.com/sap/bc/
                      ui5_ui5/ui2/ushell/shells/abap/FioriLaunchpad.html"
Set V[fiori_client] "sap-client=&V[_client]&sap-language=&V[_language2]"
Set V[fiori_object] "Customer"
Set V[fiori_action] "displaySalesOverview"
Set V[fiori_parameters] "Customer=&V[customernumber]"

Set V[fiori_url] "&V[fiori_home]?&V[fiori_client]#
                    &V[fiori_object]-&V[fiori_action]?&V[fiori_parameters]"
Start "&V[fiori_url]"  


Return "S: Customer overview started" -statusline

 

Components
InputAssistant + Controls