Native Control Interface: Read a whole tree

Example
In transaction VA03 the header texts are shown via a tree control. The user clicks on a tree node to see the corresponding text, or an empty area if no header text of this type exists:

VA03 Standard header text display Click to enlarge

Instead, we want to present all existing texts immediately:

The implementation is a little bit more complex than one would expect, since the SAP tree structure is somewhat complicated: The tree node content is different depending on whether no text, one text or more than one text - in different languages - exists for a particular text type.

To display the texts we embed an HTML control into SAP GUI. This allows us to design a user friendly layout using CSS options in HTML. Enhancements such as choosing different background colors for different text types can easily be added if required.

Public Class va03

    ' list of VA03 header texts
    Private headertexts As New List(Of Longtext)

    ' initialize
    Public Function InitTextDisplay()
        headertexts.Clear()

        Return "X"
    End Function

    ' add one header text
    Public Function AddText(ByVal id As String, _
                     ByVal title As String, ByVal language As String)

        ' new longtext object
        Dim lt As New Longtext
        lt.id = id
        lt.title = title
        lt.language = language

        ' read text from text control
        Dim tc As New guinet.TextControl
        lt.text = tc.GetText("")

        ' add text
        headertexts.Add(lt)

        ' done
        Return "X"

    End Function

    Public Function DisplayTexts(wb As SHDocVw.WebBrowser)


        ' set suitable CSS style for whole area
        Dim s As String = "<div style='font-family:Arial;
                     font-size:10pt; height:100%;  overflow-y: auto;'>"

        ' add HTML for all texts
        For Each lt As Longtext In headertexts
            s &= lt.ToHtml
        Next

        ' no text at all? then display message
        If headertexts.Count = 0 Then
            s &= "<br><br>No texts available"
        End If

        ' ending DIV
        s &= "</div>"

        ' now load the HTML into the web browser control

         Dim doc As mshtml.HTMLDocumentClass = wb.Document
        doc.body.innerHTML = s

        ' done
        Return "X"

    End Function

End Class

' VA03 long text
Public Class Longtext

    Public id As String
    Public language As String
    Public title As String
    Public text As String

    '  longtext as HTML box 
    Public Function ToHtml() As String

        ' encode in HTML format and replace carriage-return with <br>
        Dim htmltext As String = _
           System.Net.WebUtility.HtmlEncode(text).Replace(vbCr, "<br>")
        Dim htmltitle As String = 
           System.Net.WebUtility.HtmlEncode(title)

        ' choose suitable CSS style to display the text box
        Dim s As String
        s = "<div style='width:290px; height:160px; 
                         float:left; overflow-y: auto; margin:10px; "
        s &= "padding:4px; border-width: 1px; border-style: solid;
                     border-color: #404040; background-color:#f8f8f8';>"
        s &= "<b>" & htmltitle & " (" & language & ")</b><br>" _
                                      & htmltext & "</div>"

        Return s
    End Function

End Class