Purpose
Call a non-RFC function module (SD_SHIPMENT_DELIVERY_VIEW)

The Open Call Interface allows us to call up function modules which are not RFC-released. For security reasons the Open Call Interface nevertheless checks the user rights for calling the function module remotely so that you can control which function modules should be callable by GuiXT  (authorization object S_RFC).

Example
The user enters an outbound delivery number. We display delivery details via   SD_SHIPMENT_DELIVERY_VIEW.

 

 
GuiXT Script

GuiXT 
InputField (1,2) "Outbound delivery" (1,22) size=10 _ 
  name="vbeln" searchHelp="VMVL"
Pushbutton (1,39) "Read delivery" _ 
  process="read_outbound_delivery.txt" size=(1,21)

// Header data
InputField (3,2) size=72 name="shipto" -readOnly -noLabel

// Delivery items
Table (5,2) (14,78) name="deliveryitems" _
  title="&V[deliveryitems.rowcount] Items"  fixedColumns=6 -singlerowselection
Column "Item" size=6 name="posnr" -readOnly
Column "Material" size=10 name="matnr" -readOnly
Column "Text" size=36 name="arktx" -readOnly
Column "Quantity" size=12 name="lfimg" -readOnly -alignRight
Column "Unit" size=6 name="vrkme" -readOnly


InputScript "read_outbound_delivery.txt"

GuiXT 
// Table definitions for function call
CreateTable V[deliveries] vbeln
CreateTable V[deliveryheaders] name1_we ort01_we stras_we
CreateTable V[deliveryitems] posnr matnr arktx lfimg vrkme

// set delivery number
Set V[deliveries.vbeln.1] "&V[vbeln]"

// read delivery
Call "SD_SHIPMENT_DELIVERY_VIEW" _
  export.I_DELIV="deliveries" _
  import.C_VTRLK="deliveryheaders" _
  import.C_VTRLP="deliveryitems"

// set ship-to name
Set V[shipName] "&V[deliveryheaders.name1_we.1]"
Set V[shipStreet] "&V[deliveryheaders.stras_we.1]"
Set V[shipCity] "&V[deliveryheaders.ort01_we.1]"

Set V[shipto] "&V[shipName], &V[shipStreet], &V[shipCity]"


Return

Components
InputAssistant