﻿
//determine customer number from business partner number
Set V[table] "IBUPACUSTOMER"
Set V[condition] "BUSINESSPARTNER = @BU_PARTNER"
Set V[domname1] "BU_PARTNER"
Set V[domvalue1] "&F[Business Partner]"
Set V[fields] "CUSTOMER"

CreateTable V[customers] kunnr

Call /guixt/dbselect _
  export.table="table" _
  export.condition="condition" _
  export.domname1="domname1" _
  export.domvalue1="domvalue1" _
  export.fields="fields" _
  import.values="customers"

// Set keys
Set V[kunnr] "&V[customers.kunnr.1]"
Set V[vkorg] "&F[Sales Org.]"
Set V[vtweg] "&F[Distr. Channel]"
Set V[spart] "&F[Division]"

// determine start date (today minus 12 months)
Set V[diffmonths] -12
Set V[basedate] "&V[today_ymd]"

Call cl_reca_date.add_months_to_date export.id_date="basedate" export.id_months="diffmonths" import.rd_date="startdate"

// create orders table
CreateTable V[orders]  vkbur audat vbeln auart netwr waerk bstnk ernam 

// read orders
Set V[table] "VBAK"
Set V[condition] "kunnr = @KUNNR and audat >= @DATUM and vkorg = '&V[vkorg]' and vtweg = '&V[vtweg]' and spart = '&V[spart]'"
Set V[domname1] "KUNNR"
Set V[domvalue1] "&V[kunnr]"
Set V[domname2] "DATUM"
Set V[domvalue2] "&V[startdate]"
Set V[fields] "vkbur,audat,vbeln,auart,netwr,waerk,bstnk,ernam" 

Call /guixt/dbselect _
  export.table="table" export.fields="fields"   export.condition="condition" _
  export.domname1="domname1" export.domvalue1="domvalue1" _
  export.domname2="domname2" export.domvalue2="domvalue2" _
  import.values="orders"

// object variables
Set V[alv] "alv"
Set V[functions] "alvfunctions"
Set V[display] "alvdisplay"
Set V[sorts] "alvsorts"
Set V[aggregations] "alvaggregations"
Set V[sortcolumn1] "VKBUR"
Set V[sortsequence1] "1"  // ascending
Set V[sortcolumn2] "AUDAT"
Set V[sortsequence2] "2"  // descending
Set V[sortcolumn3] "VBELN"
Set V[sortsequence3] "1"  // ascending
Set V[aggregation1] "NETWR"

// ABAP-True
Set V[TRUE] "X"

// popup position/size
Set V[col1] "10"
Set V[row1] "5"
Set V[col2] "120"
Set V[row2] "40"

// Title
Set V[title] "Orders of the last 12 months"

Call BundledRequests="Start"  

// Create ALV object
Set V[alv] "alv"
Call cl_salv_table.factory export.t_table(VBAK)="orders" export.r_salv_table="alv" 

// allow all standard functions 
Call cl_salv_table.get_functions object="alv" export.value="functions" 
Call cl_salv_functions_list.set_all object="functions" export.value="TRUE" 

// Set Title
Call cl_salv_table.get_display_settings object="alv" export.value="display" 
Call cl_salv_display_settings.set_list_header object="display" export.value="title" 

// Set sort
Call cl_salv_table.get_sorts object="alv" export.value="sorts" 
Call cl_salv_sorts.add_sort object="sorts" export.columnname="sortcolumn1" export.sequence="sortsequence1"  export.subtotal="TRUE"  
Call cl_salv_sorts.add_sort object="sorts" export.columnname="sortcolumn2" export.sequence="sortsequence2"
Call cl_salv_sorts.add_sort object="sorts" export.columnname="sortcolumn3" export.sequence="sortsequence3"

// Set aggrgations
Call cl_salv_table.get_aggregations object="alv" export.value="aggregations" 
Call cl_salv_aggregations.add_aggregation object="aggregations" export.columnname="aggregation1" 

// Set popup position
Call cl_salv_table.set_screen_popup object="alv" _
  export.start_column="col1" export.start_line="row1" export.end_column="col2" export.end_line="row2"

// display popup
Call cl_salv_table.display object="alv" 

// run all calls
Call BundledRequests -dialog

Return