﻿Parameter odataservice
Parameter odataentity
Parameter sql_table
Parameter odatacolumns  ""
Parameter odatafilter   ""

if not V[odatacolumns]
  // read metadata of the valuehelp service
  CreateTable V[metadata] PropertyName 
  CallVB guinet.odata.readmetadata _
    service:="&V[odataservice]" _
    entityname:="&V[odataentity]" _
    result:="metadata"
  if V[metadata.rowcount=0]
    Return  
  endif
  // build field list from meta data
  CallSQL odatacolumns = _
    "SELECT group_concat(PropertyName, ' ') FROM V[metadata]"
else
  
  // remove comma
  Set text[temp] "&V[odatacolumns]"    
  ReplaceText "temp" from="," to=" " 
  Set V[odatacolumns] "&text[temp]"
  
endif

// create table variable from field list
CreateTable V[content] &V[odatacolumns]

// read data
CreateStructure V[msg] type message

CallVB guinet.odata.read _
  service:="&V[odataservice]/&V[odataentity]" _
  filter:="&V[odatafilter]" _
  result:="content" _
  message:="msg"

if not V[msg.type=E]
  // drop existing table and create new one
  CallSQL "DROP TABLE IF EXISTS snap.&V[sql_table]"
  CallSQL "CREATE TABLE snap.&V[sql_table] AS SELECT * FROM V[content]"
endif


Return V[msg]