Häufig sind die Bildschirme im SAP-Standard sehr umfangreich und enthalten eine Reihe nicht benötigter Felder. Das erschwert die Orientierung und das Auffinden der tatsächlich relevanten Informationen. Bei der Dateneingabe behindern die unnötigen Felder den effizienten Ablauf, und bei der Einarbeitung neuer Benutzer sind Zusatzerklärungen nötig ("In diesem Feld nichts eingeben").

Mit GuiXT können Sie sehr einfach die nicht benötigten Felder löschen und die verbliebenen neu anordnen. Wir zeigen das an einem Beispiel (MM03, Materialstammsatz, Grunddaten 1).  

Im Unterschied zu speziellen Konfigurationsmöglichkeiten innerhalb der SAP-Anwendungen (z.B. für den Materialstammsatz) funktioniert GuiXT in gleicher Weise für alle Anwendungen und Bildschirmbilder. Mit der Kenntnis weniger Anweisungen (wie del zum Löschen und pos zum Verschieben) können Sie die Masken lokal an Ihrem PC neu gestalten und dann nach Abschluss der Entwicklung für größere Benutzergruppen freigeben.  

 

       Ausgangspunkt: SAP Standardbildschirm in der Materialwirtschaft

 
 

 

        Rot markiert: die nicht benötigten Felder

Vorgehen: Klicken Sie im GuiXT Fenster auf "Script" . Es wird dann ein Texteditor für die zugeordnete Scriptdatei geöffnet. Standard ist "notepad"; wir empfehlen den Kauf unseres GuiXT Sript Editor Pro, der vielfältige Unterstützung bei der GuiXT-Entwicklung bietet.
Durch
del Befehle löschen Sie alle nicht benötigten Elemente. Dabei können Sie die Feldnamen jeweils durch Mausklick im GuiXT Fenster "Screen elements" entnehmen und mit Ctrl+V in dem Script einfügen:

del F[Ext.Warengrp.]
del
F[Werksüb. MatStatus]
del F[Labor/Büro]
del F[allg.Postypengr] -triple
del F[Gültig ab]
del C[Gültigkeit bewerten]
del F[Produkthierar.]
del G[Materialberechtigungsgruppe]
del P[Revisionsstand anzeigen]
del F[Volumen]
del F[Volumeneinheit]
del F[Größe/Abmessung]

GuiXT Fenster "Screen elements":

  

 

 

 

 

 

 

 

 

 

Dabei sind F[...] Einzelfelder, G[...] Feldgruppen mit Rahmen, P[...] Drucktasten (Pushbutton), C[...] Ankreuzfelder (Checkbox). 

 

 

     Neue Anordnung der verbliebenen Felder
 
Als nächstes verschieben Sie die verbliebenen Felder mit dem pos Befehl, um das gewünschte Layout zu erhalten:
 
// Felder und Feldgruppen verschieben
pos F[EAN/UPC-Code] F[Nettogewicht]+(1,0) 
pos F[EAN-Typ] F[EAN/UPC-Code]+(0,40) 

pos G[Allgemeine Daten] F[Material]+(2,0) 
pos G[Abmessungen/EAN] (10,1) 
pos G[Verpackungsmaterialdaten] (15,1) 
pos G[Grunddatentexte] (18,1)
 
Sie nennen bei pos jeweils das Bildschirmelement, wie bei del, und dann die neue Position. Entweder mit fixen Koordinaten (Zeile,Spalte), oder relativ zu einem anderen Bildschirmelement. 
 
Für Verkleinerung oder Vergrößerung der Gruppenrahmen können Sie "BoxSize" benutzen:
 
// Neue Rahmengrössen setzen
BoxSize G[Allgemeine Daten] (6,78)
BoxSize G[Abmessungen/EAN] (5,78) 
BoxSize G[Verpackungsmaterialdaten] (3,78)
BoxSize G[Grunddatentexte] (3,78)

 

 

      Fertiges neues Layout

Das neue Layout soll nur für "Grunddaten 1" gelten. Da das GuiXT-Script pro Bildschirm (SAP-Dynpro) abgelegt wird, aber nicht für jeden Reiter eines Bildschirms unterschiedlich, benötigen Sie noch eine Abfrage auf den aktiven Reiter "Grunddaten 1". Insgesamt sieht das Script damit wie folgt aus: 
 

// GuiXT Script saplmgmm.d4004.txt
// Materialstamm
if
Q[Page=Grunddaten 1]

  del F[Ext.Warengrp.]
  del F[Werksüb. MatStatus]
  del F[Labor/Büro]
  del F[allg.Postypengr] "-triple"
  del F[Gültig ab]
  del C[Gültigkeit bewerten]
  del F[Produkthierar.]
  del G[Materialberechtigungsgruppe]
  del P[Revisionsstand anzeigen]
  del F[Volumen]
  del F[Volumeneinheit]
  del F[Größe/Abmessung]

  // Felder und Feldgruppen verschieben
  pos F[EAN/UPC-Code] F[Nettogewicht]+(1,0)
  pos F[EAN-Typ] F[EAN/UPC-Code]+(0,40)
  pos G[Allgemeine Daten] F[Material]+(2,0)
  pos G[Abmessungen/EAN] (10,1)
  pos G[Verpackungsmaterialdaten] (15,1)
  pos G[Grunddatentexte] (19,1)

  // Neue Rahmengrössen setzen
  BoxSize G[Allgemeine Daten] (6,82)
  BoxSize G[Abmessungen/EAN] (5,82)
  BoxSize G[Verpackungsmaterialdaten] (4,82)
  BoxSize G[Grunddatentexte] (3,82)

endif

Falls Sie das neue Layout nur in der Materialanzeige haben möchten (Transaktion MM03), bei "Hinzufügen" oder "Ändern" aber ein davon abweichendes, können Sie das steuern durch

// Abfrage auf Transaktion MM03
if Q[Transaction=MM03]
 
...
endif