GuiXT bietet die Möglichkeit, Wertemengen (z.B. 1,2,3 bei "Lieferplaneinteilungen") direkt als Gruppe von Radiobuttons in das Bild zu integrieren. Damit wird dem ungeübten Benutzer die Bedienung der Transaktion wesentlich erleichtert. Es entfällt der wiederholte Aufruf der F4-Wertehilfe auf dem Bild. Aber auch für geübte Benutzer ist bei kleinen Wertemengen, die man auf einen Blick überschaut, die Auswahl über Radiobuttons schneller.
Als weitere Verbesserungen belegen wir einige Felder (z.B. Planungsumfang) mit einem festen Wert und blenden das Eingabefeld aus. Die letzte Eingabegruppe für den User-Exit streichen wir ganz. Damit sieht die Eingabemaske z.B. so aus:
Was haben wir damit erreicht?
- Weniger Fehlermöglichkeiten durch falsche Eingaben
- Leichtere Bedienung
- Geringerer Schulungsaufwand
Das GuiXT Script dazu arbeitet mit der "Offset" Anweisung, mit der sich Blöcke aus mehreren Bildelementen während der Scriptentwicklung leichter hin- und herschieben lassen.
GuiXT
// -------------------------------------------
// Werk
// -------------------------------------------
Offset (0,1)
Box (0,0) (5,60) "Planungslauf für Werk"
Radiobutton (2,2) "1000 Hamburg" [Werk] "1000"
Radiobutton (3,2) "1100 Berlin" [Werk] "1100"
Radiobutton (4,2) "1200 Dresden" [Werk] "1200"
Default [Werk] "1000"
Box (6,0) (21,60) "Einstellungen für den Planungslauf"
// -------------------------------------------
// Terminierung
// -------------------------------------------
Offset (8,3)
Box (0,0) (3,40) "Terminierung"
Radiobutton (1,1) "Ecktermin" F[Terminierung] "1"
Radiobutton (2,1) "Durchlauf" F[Terminierung] "2"
// -------------------------------------------
// Lieferplaneinteilungen
// -------------------------------------------
Offset (12,3)
Box (0,0) (3,40) "Lieferplaneinteilungen"
Radiobutton (1,1) "Ja" F[Lieferplaneinteilungen] "3"
Radiobutton (2,1) "Nein" F[Lieferplaneinteilungen] "1"
// -------------------------------------------
// Planungsmodus
// -------------------------------------------
Offset (16,3)
Box (0,0) (4,40) "Planungsmodus"
Radiobutton (1,1) "Planungsdaten reaktivieren" F[Planungsmodus] "1"
Radiobutton (2,1) "Planungsdaten zurücksetzen" F[Planungsmodus] "3"
Radiobutton (3,1) "Stücklistendaten zurücksetzen" F[Planungsmodus] "2"
// -------------------------------------------
// Start-Button
// -------------------------------------------
Offset (19,64)
Pushbutton (0,0) "Starten " "/0" size=2
// -------------------------------------------
// Feste Werte setzen
// -------------------------------------------
Set F[Verarbeitungsschlüssel] "NETCH"
Set F[Planungsmodus] "1"
Set F[Dispoliste erstellen] "1"
Set F[Planungsumfang] "9999"
// -------------------------------------------
// Nicht benötigte Felder löschen
// -------------------------------------------
del F[Werk] "-triple"
del G[Steuerungsparameter Disposition]
del G[Steuerungsparameter Ablauf]
del G[User-Ex.]
del F[Planungsumfang] "-triple"